***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 18, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt MMSZ5230AS-AU A K 
.param
+vc0 = 1.196e-11	 vc1 = 1.383e-10 	 vc2 = 1.000e0		 vc3 = 3.591e-9		 vc4 = 9.270e0
+tc1 = 1.351e-2		 tc2 = 1.521e-2		 tc3 = 5.191e-3		 tc4 = 1.201e-4	   
.func irpwr(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v**vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 2.247e-15	   n = 1.054		  rs = 4.884e-1
+ibv = 5e-3		 nbv = 1.0		  bv = 4.7
+ikf = 1.075e-1
***** capacitance parameter *****
+cjo = 1.521e-10	   m = 3.784e-1		  vj = 8.389e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.1		 xti = 3
+trs1 = 8.325e-4	trs2 = 1.025e-5
+tbv1 = -6.228e-5	tbv2 = -6.456e-7	tikf = 4e-2
.ends MMSZ5230AS-AU
*$
